Quelcode IR8 von Pollin

Hallo Zusammen,

möchte einen Assembler quellcode änder weis aber nicht wie?
Ich habe mir eine IR8 von Pollin bestellt. Das ist ein Vernbedinugs emfänger der Relais schalten kann. In der Schaltung wurde ein Programiebarer Atiny2313 verwendet. die Originale einprogrammierte Software konnte ich nicht auslesen. Habe mich im Internet umgeschaut und hab einen quellcode gefunden der auch Funktioniert aber nicht ganz für mein Projekt geeignet ist.
Kann man den quellcode so veränder das Alle Relais mit einer Taste bedient werden. Die Relais1 bis Relais7 ca. mit 3 sec. Verzögerung angezogen werden und die Relais8 ohne Verzögerung --> Andersherum beim Ausschalten die Relais 1 bis 7 sofort loslassen und die Relais8 nach ca. 0,5 bis 1 sec.

Könnten ihr bitte helfen???
Das ist der Bausatz:

http://www.pollin.de...ngs_Bausatz_IR8.html

Gefunden habe ich den quellcode hier:

http://www.mikrocontroller.net/topic/59459#1529395





Gruß
Jakob

das ist der Quelcode:

/*
Alternativ-Firmware für IR8-Bausatz Version 1.2 von Pollin
Der ATTiny2313 sollte im Originalzustand gefust sein, also mit aktiviertem
internen 8MHz-RC-Oszillator. Achtung: Der zum Bausatz gehörende ATTiny2313
ist auf 4MHz gefust. Der Zustand der CKDIV8-Fuse ist egal, der Taktvorteiler
wird per Programm auf 1:1 (8MHz) eingestellt. Es schadet nicht, wenn man
den BOD aktiviert.

Als Fernbedienung kommt die zur Version 1.2 mitgelieferte "Infrared Remote
Control" zum Einsatz, die über 37 Tasten verfügt, mit einem Siemens-IC
SDA2008 bestückt ist und mit einem 9Volt-Block betrieben wird. Diese
sendet das IR60-Protokoll.

Alle empfangenen Telegramme werden am TXD-Pin der RS232-Schnittstelle mit
einer Baudrate von 19200 Baud ausgegeben. Das erste Byte eines jeden
Telegramms wird unverändert übertragen, die Folgebytes desselben Telegramms
werden mit gesetztem Bit 7 übertragen. Dies ermöglicht die Unterscheidung
eines neuen Tastendruckes von einem langen Tastendruck.

Die Zuweisung der Schaltaktionen aller Tasten wird in der Include-Datei
"schaltparameter.inc" definiert. Hier kann jedem Tastencode der Schaltmodus,
die Schaltzeit und die an der Schalthandlung beteiligten Portpins zugewiesen
werden. Als Schaltmodi gelten:

imp: Impuls definierter Dauer unabhängig von der Tastendruckdauer
rep: Repeat, Impuls von der Dauer des Tastendrucks + min. 100 ms
tog: Toggeln des/der Portpin(s), die angegebene Zeit wird ignoriert
aus: Ausschalten der Portpins ohne Einschalten nach angegebener Zeit

Da die Fernbedienung 37 Tasten hat, können bis zu 37 Datensätze (Zeilen)
in die Tabelle in der Datei "schaltparameter.inc" eingetragen werden.
Leider sind einige Tastencodes doppelt vergeben (oder fehlerhaft decodiert).

*/
.include "tn2313def.inc" ;Namen benannter Bytes und Bits bekannt machen
.include "deklara.inc" ;Konstanten und Variablen

;Beginn des Programmspeichers, reservierte Adressen für Reset und Interrupts:
.cseg ;Programmspeicher
.org 0 ;ab Adresse 0
rjmp RESET ;Reset Handler
rjmp exti0 ;External Interrupt0 Handler
rjmp nix;INT1 ;External Interrupt1 Handler
rjmp nix;TIM1_CAPT ;Timer1 Capture Handler
rjmp TIM1_COMPA ;Timer1 CompareA Handler
rjmp nix;TIM1_OVF ;Timer1 Overflow Handler
rjmp nix;TIM0_OVF ;Timer0 Overflow Handler
rjmp nix;USART0_RXC ;USART0 RX Complete Handler
rjmp nix;USART0_DRE ;USART0,UDR Empty Handler
rjmp nix;USART0_TXC ;USART0 TX Complete Handler
rjmp nix;ANA_COMP ;Analog Comparator Handler
rjmp nix;PCINT ;Pin Change Interrupt
rjmp TIM1_COMPB ;Timer1 Compare B Handler
rjmp nix;TIMER0_COMPA ;Timer0 Compare A Handler
rjmp nix;TIMER0_COMPB ;Timer0 Compare B Handler
rjmp nix;USI_START ;USI Start Handler
rjmp nix;USI_OVERFLOW ;USI Overflow Handler
rjmp nix;EE_READY ;EEPROM Ready Handler
rjmp nix;WDT_OVERFLOW ;Watchdog Overflow Handler

nix: ;eine Falle für unerlaubte Interrupts (Prog-Fehler)
rjmp nix ;Falle...
; reti ;zurück...

reset: ;Initialisierung
clr null ;immer 0
ldi wl,1<<clkpce ;Schreibschutz Taktvorteiler
out clkpr,wl ;aufheben
out clkpr,null ;Teilerfaktor
out clkpr,null ;1 zu 1
nop ;Zeit zum Einschwingen geben
ldi wl,low(ramend) ;Stackpointer
out spl,wl ;initialisieren
clr flags
;Ports
ldi wl,$ff ;alle Pins von
out porta,null ;L-Pegel an PortA
out portb,null ;L-Pegel an PortB
out ddra,wl ;PortA als Ausgang
out ddrb,wl ;PortB als Ausgang
ldi wl,0b00000111 ;an PortD TXD auf H, Pullup RXD
out portd,wl ;und Int0 ein
ldi wl,0b11111010 ;PortD alles außer RXD und Int0
out ddrd,wl ;als Ausgang
;UART
ldi wl,low(ubr) ;Baudrate
out ubrrl,wl ;für
ldi wl,high(ubr) ;UART
out ubrrh,wl ;einstellen
ldi wl,1<<txen ;UART-Senden (TX)
out ucsrb,wl ;aktivieren
ldi wl,(1<<ucsz1)|(1<<ucsz0)|(1<<usbs) ;8-Bit-Mode
out ucsrc,wl ;und 2 Stoppbits einstellen
;ext.Interrupt 0 und Sleep
ldi wl,extib ;beide Flanken für Int0 einstellen
out mcucr,wl ;und Sleep-Mode IDLE vorwählen
ldi wl,1<<int0 ;Int0
out gimsk,wl ;freigeben
;Timer
ldi wl,low(intervalla) ;ersten
ldi wh,high(intervalla) ;Compare1A-Interrupt
out ocr1ah,wh ;auf 10 ms
out ocr1al,wl ;terminieren
ldi wl,4 ;Timer 1 mit Vorteiler 1:256
out tccr1b,wl ;einschalten (32 µs je Zahlenwert)
ldi wl,ocbein ;beide Comp1-Int
out timsk,wl ;freigeben
;divers
ldi xl,low(teltout+1) ;Pointer hinter das Ende
ldi xh,high(teltout+1) ;der Timeout-Zähler
reset1: ;Loop
st -x,null ;RAM für Timeout-Zähler und TX-Puffer löschen
cpi xl,txbuffer ;Anfang erreicht?
brne reset1 ;nein, nochmal...
sts lepo,xl ;Lesepointer setzen
sei ;Interrupts freigeben


mainloop: ;Hauptschleife
lds yl,lepo ;Lesepointer holen
cp xl,yl ;Enthält TX-Puffer Daten?
breq mainloop1 ;nein, weiter...
rcall job_sendbyte ;ja, senden...
mainloop1:
sbrc flags,neubyte ;neues Telegramm eingetroffen?
rjmp job_neues_byte ;ja, abarbeiten...
sbrc flags,neu10ms ;sind 10 Millisekunde vergangen? - nein...
rjmp job_10ms ;ja, abarbeiten...
sleep ;CPU-Takt bis zum nächsten Interrupt aus
rjmp mainloop ;nochmal...


job_sendbyte: ;Job der Mainloop, sendet ein Byte per UART
sbis ucsra,udre ;ist UART busy? - nein...
ret ;ja, fertig, später noch mal probieren...
clr yh ;RAM liegt in Page 0
ld wl,y+ ;Byte aus Puffer lesen
out udr,wl ;und versenden
sbrs yl,5 ;Puffer-Ende erreicht? - nein...
ldi yl,txbuffer ;ja, Pointer auf Anfang setzen
sts lepo,yl ;Pufferpointer wieder sichern
ret ;fertig...


job_10ms: ;Job der Mainloop, Aufruf alle 10 Millisekunden
cbr flags,1<<neu10ms ;Jobauftrag entwerten
;erstmal Telegramm-TimeOut managen
lds wl,teltout ;Telegramm-Timeout holen,
tst wl ;schon abgelaufen?
breq job_10ms1 ;ja, nicht behandeln
dec wl ;nein, herunterzählen und
sts teltout,wl ;wieder sichern
brne job_10ms1 ;jetzt abgelaufen? - nein...
cbr flags,1<<adress ;weitere Bytes als ungültig markieren
job_10ms1: ;Ausgänge abschalten
ldi yl,low(toz) ;Pointer auf Timeout-Zähler
ldi yh,high(toz) ;im SRAM
ldi zl,low(bimu*2) ;Pointer auf Bitmustertabelle
ldi zh,high(bimu*2) ;im Flash
job_10ms1a:
ld wl,y ;TimeOut-Zähler holen
tst wl ;TimeOut aktiv?
breq job_10ms1b ;nein...
dec wl ;herunterzählen
st y,wl ;und sichern
brne job_10ms1b ;abgelaufen? - nein...
adiw zh:zl,3 ;Tastencode, Mode und Schaltzeit überspringen
lpm r0,z+ ;Bitmuster PortA holen
com r0 ;und invertieren
in r1,porta ;zu ändernden Port einlesen
and r1,r0 ;Bit löschen
out porta,r1 ;und zurückschreiben
lpm r0,z+ ;Bitmuster PortB holen
com r0 ;und invertieren
in r1,portb ;zu ändernden Port einlesen
and r1,r0 ;Bit löschen
out portb,r1 ;und zurückschreiben
lpm r0,z+ ;Bitmuster PortD holen
com r0 ;und invertieren
in r1,portd ;zu ändernden Port einlesen
and r1,r0 ;Bit löschen
out portd,r1 ;und zurückschreiben
sbiw zh:zl,6 ;Pointer korrigieren
job_10ms1b:
adiw zh:zl,6 ;Flash-Pointer auf nächsten Datensatz
adiw yh:yl,1 ;SRAM-Pointer auf nächsten Timeout-Zähler
cpi zl,low(endbimu*2) ;letzter Datensatz fertig?
brne job_10ms1a ;ja, nochmal...
rjmp mainloop ;fertig...


job_neues_byte: ;es ist ein neues Byte eingetroffen
cbr flags,1<<neubyte ;Jobflag entwerten
ldi yl,low(toz-1) ;Pointer vor Timeout-Zähler
ldi yh,high(toz-1) ;im SRAM
ldi zl,low(bimu*2-5) ;Pointer 5 vor Bitmustertabelle
ldi zh,high(bimu*2-5) ;im Flash
lds wl,cmd ;Byte holen
bst wl,repeat ;Repeat-Bit sichern
andi wl,63 ;und löschen
job_neues_byte1:
adiw zh:zl,5 ;Bitmusterbytes kompensieren
adiw yh:yl,1 ;Timeout-Index mitzählen
cpi zl,low(endbimu*2) ;letzter Datensatz fertig?
breq job_neues_byte_e ;ja, Abbruch, Code nicht gefunden...
lpm r0,z+ ;Tastencode aus Tabelle holen
cp r0,wl ;identisch?
brne job_neues_byte1 ;nein, nächsten Datensatz prüfen
;Tastencode wurde in Tabelle gefunden
lpm wh,z+ ;Mode-Bits holen
lpm wl,z+ ;Schaltzeit holen
lpm r0,z+ ;Bitmuster PortA holen
sbrs wh,toggel ;hat dieser Portpin Toggelmode? - ja...
rjmp job_neues_byte2 ;nein, weiter...
;dieser Schaltbefehl hat Toggelmode
brts job_neues_byte_e ;ja, Repeat-Bit im empfangenen Byte? - ja...
;es ist das erste Byte des Telegramms
in r1,porta ;Port einlesen,
eor r1,r0 ;Bit toggeln
out porta,r1 ;und zurückschreiben
lpm r0,z+ ;Bitmuster PortB holen
in r1,portb ;Port einlesen,
eor r1,r0 ;Bit toggeln
out portb,r1 ;und zurückschreiben
lpm r0,z+ ;Bitmuster PortD holen
in r1,portd ;Port einlesen,
eor r1,r0 ;Bit toggeln
out portd,r1 ;und zurückschreiben
rjmp job_neues_byte_e ;fertig...
job_neues_byte2: ;es war kein Toggel-Mode
sbrs wh,repeat ;Repeat-Bit in Tabelle gesetzt? - ja...
brts job_neues_byte_e ;nein, Repeat-Bit im empfangenen Byte? - ja...
sbrc wh,nuraus ;soll nur ausgeschaltet werden? - nein...
rjmp job_neues_byte3 ;ja, Porteinschalten überspringen...
in r1,porta ;Port einlesen,
or r1,r0 ;Bit setzen
out porta,r1 ;und zurückschreiben
lpm r0,z+ ;Bitmuster PortB holen
in r1,portb ;Port einlesen,
or r1,r0 ;Bit setzen
out portb,r1 ;und zurückschreiben
lpm r0,z+ ;Bitmuster PortD holen
in r1,portd ;Port einlesen,
or r1,r0 ;Bit setzen
out portd,r1 ;und zurückschreiben
job_neues_byte3:
st y,wl ;Schaltzeit setzen
job_neues_byte_e:
rjmp mainloop ;fertig...


exti0: ;ISR, externer Interrupt, Impuls vom TSOP1736
in srsk,sreg ;PSW sichern
in it3,tcnt1l ;Zeitstempel
in it4,tcnt1h ;holen
mov it1,it3 ;und
mov it2,it4 ;kopieren
sub it1,zsl ;Impulsbreite (Differenz neu-alt)
sbc it2,zsh ;berechnen
mov ibl,it1 ;und
mov ibh,it2 ;sichern
mov zsl,it3 ;Zeitstempel dieses Interrupts
mov zsh,it4 ;als Impulsbeginn merken
cpi status,17 ;relevanter Teil das Telegramms fertig?
brlo exti00 ;nein, weiter...
rjmp exti0_15plus ;ja, separat behandeln...
exti00: ;Telegramm ist noch nicht fertig
cpi status,3 ;ist Pre-Signal und Startbit schon durch?
brsh exti01 ;ja, weiter...
rjmp exti0_pre ;nein, separat behandeln...
exti01: ;Telegramm ist im Datenbitbereich
tst it2 ;viel zu lange Impulsdauer?
brne exti00e ;ja, Error...
cpi it1,iblimitu ;Impulsdauer zu kurz?
brlo exti00e ;ja, Error...
cpi it1,iblimito ;Impulsdauer zu lang?
brlo exti02 ;nein, es war ein gültiger kurzer Impuls
cpi it1,iblimitu*2 ;doppelte Impulsdauer zu kurz?
brlo exti00e ;ja, Error...
cpi it1,iblimito*2 ;doppelte Impulsdauer zu lang?
brlo exti03 ;nein, es war ein gültiger langer Impuls
exti00e:
rjmp exti0_err ;Fehler...
exti02: ;kurzen Impuls empfangen
sbrc status,1 ;ist Status ungeradzahlig? - ja...
rjmp exti0es1 ;nein, nicht shiften, Status erhöhen und fertig...
lsr shiftreg ;Bits weitershiften
sbrs flags,bit ;ist Bitwert=1? - nein...
sbr shiftreg,32 ;ja, Shiftbit setzen
rjmp exti0es1 ;Status erhöhen und fertig...
exti03: ;langen Impuls empfangen
ldi it2,1<<bit ;Bitwert
eor flags,it2 ;toggeln
lsr shiftreg ;Bits weitershiften
sbrs flags,bit ;ist Bitwert=1? - nein...
sbr shiftreg,32 ;ja, Shiftbit setzen
rjmp exti0es2 ;Status doppelt erhöhen und fertig...
exti0_pre: ;vor dem Datenbitbereich
cpi status,0 ;Wartephase auf das Pre-Signal?
brne exti0_pre1 ;nein, weiter...
;Bereitschaft, es wurde noch kein Bit empfangen, Beginn des Pre-Signals
sbic pind,irbit ;ist jetzt L-Pegel geworden? - ja...
rjmp exti0_err ;nein, Fehler...
sbrc flags,akt ;Empfang schon aktiv? - nein...
rjmp exti0_err ;ja, Fehler...
exti0_pre0:
;Pause war groß genug, es ist Impulsbeginn (L-aktive Impulse)
sbr flags,1<<akt ;Telegrammempfang als aktiv markieren
sbi ledport,ledbit
rjmp exti0es1 ;Status erhöhen und fertig...
exti0_pre1:
cpi status,1 ;Ende Pre-Signal?
brne exti0_pre1a ;nein, weiter...
;Impulsende des Pre-Signals
cbi ledport,ledbit ;Busy-LED aus
ldi it1,77 ;Pre-Pause
add zsl,it1 ;alten Zeitstempel um 4 Impulsbreiten
adc zsh,null ;vordatieren (Pre-Pause kompensieren)
mov it1,ibl ;akt. Zeitstempel
exti0_pre1a: ;Einsprung aus 2 und 3
cpi it2,0 ;Impulsbreite viel zu groß?
brne exti0_pre1b ;ja...
cpi it1,iblimito ;Impulsbreite zu groß?
brsh exti0_pre1b ;ja...
cpi it1,iblimitu ;Impulsbreite zu klein?
brlo exti0_pre1b ;ja...
rjmp exti0_pre1c ;nein, Impulsbreite ok...
exti0_pre1b: ;Impulsbreite fehlerhaft
rjmp exti0_err ;
exti0_pre1c: ;Impulsbreite Pre-Signal ist ok
sbr flags,1<<bit ;mit Einsbit beginnen
rjmp exti0es1 ;Status erhöhen und fertig...
exti0_15plus: ;es wurden bereits mehr als 6 Bits eingesammelt
cbr status,64 ;Überlauf verhindern
exti0_15plus1:
rjmp exti0e ;fertig...
exti0_err: ;Error Impulsbreite
sbr status,32 ;Error-Bit setzen
rjmp exti0es1 ;weiter...
exti0es2: ;Ende langer Impuls (Status um 2 erhöhen)
inc status ;Status erhöhen
exti0es1: ;Ende kurzer Impuls (Status um 1 erhöhen)
inc status ;Status erhöhen
ldi it1,low(iblimito*25) ;Byte-Timeout
ldi it2,high(iblimito*25) ;auf
add it1,zsl ;jetzt
adc it2,zsh ;plus
out ocr1bh,it2 ;6 Impulslimits
out ocr1bl,it1 ;setzen
ldi it2,telzeit ;Telegramm-TimeOut
sts teltout,it2 ;auf Startwert setzen
exti0e: ;Ende ohne Statusänderung
out sreg,srsk ;PSW wiederherstellen
reti ;fertig...


tim1_compa: ;ISR, Timer1 CompareA, Zeitbasis 10 ms
in srsk,sreg ;PSW sichern
sbr flags,1<<neu10ms ;Job 10ms anmelden
in it1,ocr1al ;Auslösetermin dieses
in it2,ocr1ah ;Interrupts holen
subi it1,low(-intervalla) ;Intervall für 10 ms
sbci it2,high(-intervalla) ;aufaddieren
out ocr1ah,it2 ;als Termin für nächsten
out ocr1al,it1 ;Interrupt setzen
out sreg,srsk ;PSW wiederherstellen
reti ;fertig...


tim1_compb: ;ISR, Timer1 CompareB, Telegramm-Bit-Timeout
in srsk,sreg ;PSW sichern
cbr flags,1<<akt ;Byte-Empfang als beendet markieren
cpi status,15 ;erlaubte Anzahl Bits empfangen?
breq tim1_compb1 ;ja, Telegramm ist ok...
cpi status,16 ;erlaubte Anzahl Bits empfangen?
breq tim1_compb1 ;ja, Telegramm ist ok...
rjmp tim1_compb_e ;nein, Telegramm verwerfen...
tim1_compb1:
sbrs flags,adress ;ist die Startkennung schon durch? - ja...
rjmp checkadress ;nein, weiter
;Adresse (Startbyte) wurde bereits empfangen
cpi shiftreg,62 ;war es das Stoppbyte?
brne tim1_compb2 ;nein...
cbr flags,1<<adress ;ja, eventuelle Restbytes entwerten
ldi shiftreg,255 ;Merkbytes der Entprellung und Repeaterkennung
rjmp tim1_compb5 ;entwerten...
tim1_compb2:
cp shiftreg,alt ;wurde dieses Byte bereits empfangen?
brne tim1_compb5 ;nein, Bytes nachrücken lassen und Ende...
clr it1 ;ja, Bits und Wiederhol-Kennung erstmal löschen
cp shiftreg,uralt ;wurde dieses Byte bereits mehrfach empfangen?
brne tim1_compb3 ;nein, noch nicht...
sbr it1,1<<repeat ;ja, Wiederhol-Kennung setzen
tim1_compb3:
or it1,shiftreg ;Nutzbyte zur Repeatkennung kopieren
sts cmd,it1 ;Nutzbyte sichern
sbr flags,1<<neubyte ;und anmelden
st x+,it1 ;Nutzbyte in den Sendepuffer
sbrs xl,5 ;Puffer-Ende erreicht? - nein...
ldi xl,txbuffer ;ja, Pointer auf Anfang setzen
rjmp tim1_compb5 ;Bytes nachrücken lassen und Ende...
checkadress: ;Telegramm auf Startbyte prüfen
cpi shiftreg,62 ;Startbyte?
brne tim1_compb_e ;nein, Byte verwerfen...
;Byte war ein gültiges Startbyte
sbr flags,1<<adress ;Telegramm als gültig markieren
rjmp tim1_compb_e ;fertig...
tim1_compb5: ;Byte war ein Nutzbyte
mov uralt,alt ;Bytewerte
mov alt,shiftreg ;nachrücken lassen
clr shiftreg ;
tim1_compb_e: ;Ende
clr status ;Bitzähler von vorn beginnen
out sreg,srsk ;PSW wiederherstellen
reti ;fertig...

bimu: ;Bitmuster für Portpins
.include "schaltparameter.inc" ;Datei mit Daten zum Schaltverhalten
endbimu: